2.9BSD - /usr/src/sys/conf/sc21boot.s

   1: /*
   2:  *	SCCS id	@(#)boot.s	1.2 (Berkeley)	9/6/82
   3:  */
   4: #include "whoami.h"
   5: 
   6: #ifdef  UCB_AUTOBOOT
   7: /  The boot options and device are placed in the last SZFLAGS bytes
   8: /  at the end of core for the bootstrap.
   9: ENDCORE=        160000          / end of core, mem. management off
  10: SZFLAGS=        6               / size of boot flags
  11: BOOTOPTS=       2               / location of options, bytes below ENDCORE
  12: BOOTDEV=        4
  13: CHECKWORD=      6
  14: 
  15: reset=  5
  16: 
  17: .globl  _doboot, hardboot
  18: .text
  19: _doboot:
  20:         mov     4(sp),r4        / boot options
  21:         mov     2(sp),r3        / boot device
  22: 
  23: #ifndef KERN_NONSEP
  24: /  If running separate I/D, need to turn off memory management.
  25: /  Call the routine unmap in low text, after setting up a jump
  26: /  in low data where the PC will be pointing.
  27: .globl  unmap
  28:         mov     $137,*$unmap+2          / jmp *$hardboot
  29:         mov     $hardboot,*$unmap+4
  30:         jmp     unmap
  31:         / "return" from unmap will be to hardboot in data
  32: .data
  33: #else
  34: /  Reset to turn off memory management
  35:         reset
  36: #endif
  37: 
  38: /  On power fail, hardboot is the entry point (map is already off)
  39: /  and the args are in r4, r3.
  40: 
  41: hardboot:
  42:         mov     r4, ENDCORE-BOOTOPTS
  43:         mov     r3, ENDCORE-BOOTDEV
  44:         com     r4              / if CHECKWORD == ~bootopts, flags are believed
  45:         mov     r4, ENDCORE-CHECKWORD
  46: 1:
  47:         reset
  48: 
  49: /  The remainder of the code is dependent on the boot device.
  50: /  If you have a bootstrap ROM, just jump to the correct entry.
  51: /  Otherwise, use a BOOT opcode, if available;
  52: /  if necessary, read in block 0 to location 0 "by hand".
  53: 
  54: /  Bootstrap for Emulex SC21 with boot opcode
  55: 
  56: unit =  0               /  unit to boot from
  57: RMCS1=  176700
  58: RMCS2=  176710
  59: RMHR=   176736
  60: BOOT=   75
  61:         mov     $RMCS1,r0
  62:         mov     $unit, RMCS2
  63:         mov     $-1, RMHR       / enable extended opcodes
  64:         mov     $BOOT,(r0)
  65: 2:      tstb    (r0)
  66:         bpl     2b              / wait for done (RDY)
  67:         tst     (r0)
  68:         bmi     1b              / try again on error (TRE)
  69: 
  70:         jmp     *$0
  71: / no return
  72: #endif	UCB_AUTOBOOT

Defined functions

Defined variables