UNIX 6th Ed. - /usr/source/fort/f1/f17.s

   1: /
   2: /
   3: 
   4: / f17 -- implicit statement
   5: 
   6: .globl  simpl
   7: 
   8: .globl  getype
   9: .globl  chrtab
  10: .globl  error
  11: 
  12: simpl:
  13:         jsr     r5,getype
  14:                 br 9f
  15:         mov     r2,r1
  16:         mov     r0,-(sp)
  17:         movb    (r1)+,r0
  18:         cmp     r0,$'(
  19:         beq     1f
  20:         cmpb    r0,$'/
  21:         bne     8f
  22: 1:
  23:         movb    (r1)+,r0
  24:         cmpb    chrtab(r0),$2
  25:         bne     8f
  26:         cmpb    r0,$'a
  27:         blo     2f
  28:         sub     $6,r0           / map 'a into 'Z+1
  29: 2:
  30:         movb    (r1)+,r2
  31:         cmpb    r2,$'-
  32:         bne     2f
  33:         movb    (r1)+,r2
  34:         cmpb    chrtab(r2),$2
  35:         bne     8f
  36:         cmp     r2,$'a
  37:         blo     3f
  38:         sub     $6,r2           / map 'a into 'Z+1
  39:         br      3f
  40: 2:
  41:         mov     r0,r2
  42:         dec     r1
  43: 3:
  44:         cmp     r0,r2
  45:         bhi     8f
  46:         asl     r0
  47:         asl     r2
  48: 3:
  49:         mov     (sp),imptab-[2*'A](r0)
  50:         add     $2,r0
  51:         cmp     r0,r2
  52:         blos    3b
  53:         movb    (r1)+,r0
  54:         cmp     r0,$',
  55:         beq     1b
  56:         tst     (sp)+
  57:         cmp     r0,$')
  58:         beq     1f
  59:         cmp     r0,$'/
  60:         bne     9f
  61: 1:
  62:         tstb    (r1)
  63:         bne     simpl
  64:         rts     r5
  65: 8:
  66:         tst     (sp)+
  67: 9:
  68:         jsr     r5,error; 16.   / implicit syntax error
  69:         rts     r5

Defined functions