UNIX 6th Ed. - /usr/source/fort/rt/r1.s

   1: /
   2: /
   3: 
   4: / r1 -- fortran runtime
   5: 
   6: .globl  gas1
   7: .globl  gas2
   8: .globl  gas4
   9: .globl  gas8
  10: .globl  stop
  11: .globl  lval
  12: .globl  rval4
  13: .globl  rval8
  14: .globl  do1
  15: .globl  do12
  16: .globl  do14
  17: .globl  do2
  18: .globl  do22
  19: .globl  do24
  20: .globl  goto
  21: .globl  cgoto
  22: .globl  cagoto
  23: .globl  agoto
  24: 
  25: .globl  rerr
  26: 
  27: gas8:
  28:         mov     8.(sp),r0
  29:         mov     (sp)+,(r0)+
  30:         mov     (sp)+,(r0)+
  31:         br      1f
  32: 
  33: gas1:
  34:         movb    (sp)+,*(sp)+
  35:         jmp     *(r4)+
  36: 
  37: gas2:
  38:         mov     (sp)+,*(sp)+
  39:         jmp     *(r4)+
  40: 
  41: gas4:
  42:         mov     4(sp),r0
  43: 1:
  44:         mov     (sp)+,(r0)+
  45:         mov     (sp)+,(r0)
  46:         tst     (sp)+
  47:         jmp     *(r4)+
  48: 
  49: stop:
  50:         sys     exit
  51: 
  52: lval:
  53:         mov     (r4)+,-(sp)
  54:         jmp     *(r4)+
  55: 
  56: rval8:
  57:         mov     (r4)+,r0
  58:         add     $8.,r0
  59:         mov     -(r0),-(sp)
  60:         mov     -(r0),-(sp)
  61:         mov     -(r0),-(sp)
  62:         mov     -(r0),-(sp)
  63:         jmp     *(r4)+
  64: 
  65: rval4:
  66:         mov     (r4)+,r0
  67:         mov     2(r0),-(sp)
  68:         mov     (r0),-(sp)
  69:         jmp     *(r4)+
  70: 
  71: do22:
  72:         mov     (sp)+,r1
  73:         br      1f
  74: 
  75: do12:
  76:         mov     $1,r1
  77: 1:
  78:         mov     (sp)+,r2
  79:         mov     (sp)+,r0
  80:         add     r1,(r0)
  81:         cmp     (r0),r2
  82:         bgt     goto
  83:         tst     (r4)+
  84:         jmp     *(r4)+
  85: 
  86: do24:
  87: do2:
  88:         mov     (sp)+,r2
  89:         mov     (sp)+,r1
  90:         br      1f
  91: 
  92: do14:
  93: do1:
  94:         clr     r2
  95:         mov     $1,r1
  96: 1:
  97:         mov     4(sp),r0
  98:         add     r1,2(r0)
  99:         adc     r2
 100:         add     r2,(r0)
 101:         cmp     (r0)+,(sp)+
 102:         bgt     1f
 103:         blt     2f
 104:         cmp     (r0),(sp)
 105:         bhi     1f
 106: 2:
 107:         cmp     (sp)+,(sp)+
 108:         tst     (r4)+
 109:         jmp     *(r4)+
 110: 
 111: 1:
 112:         cmp     (sp)+,(sp)+
 113: goto:
 114:         mov     (r4),r4
 115:         jmp     *(r4)+
 116: 
 117: cgoto:
 118:         tst     (sp)+
 119:         mov     (sp)+,r0
 120:         asl     r0
 121:         add     r4,r0
 122: 1:
 123:         tst     (r4)+
 124:         beq     gotoe
 125:         cmp     r0,r4
 126:         bne     1b
 127:         mov     -(r0),r4
 128:         jmp     *(r4)+
 129: cagoto:
 130:         tst     (sp)+
 131:         mov     (sp)+,r0
 132: 1:
 133:         tst     (r4)
 134:         beq     gotoe
 135:         cmp     r0,(r4)+
 136:         bne     1b
 137:         mov     r0,r4
 138:         jmp     *(r4)+
 139: 
 140: agoto:
 141:         tst     (sp)+
 142:         mov     (sp)+,r4
 143:         jmp     *(r4)+
 144: 
 145: gotoe:
 146:         jsr     r5,rerr; 14.

Defined functions