UNIX 6th Ed. - /usr/source/fort/rt/r2.s

   1: /
   2: /
   3: 
   4: / r2 -- comparison of 4-byte integers
   5: 
   6: .globl  ilt4
   7: .globl  ile4
   8: .globl  ieq4
   9: .globl  ine4
  10: .globl  ige4
  11: .globl  igt4
  12: .globl  lan2
  13: .globl  lor2
  14: .globl  lnt2
  15: .globl  ieq2
  16: .globl  ile2
  17: .globl  igt2
  18: .globl  ige2
  19: .globl  leq2
  20: .globl  ine2
  21: .globl  ilt2
  22: .globl  lne2
  23: .globl  leq1
  24: .globl  lne1
  25: 
  26: ilt4:
  27:         jsr     pc,compar
  28:         blt     one
  29:         br      zero
  30:         blo     one
  31:         br      zero
  32: 
  33: ile4:
  34:         jsr     pc,compar
  35:         ble     one
  36:         br      zero
  37:         blos    one
  38:         br      zero
  39: 
  40: ieq4:
  41:         jsr     pc,compar
  42:         beq     one
  43:         br      zero
  44:         beq     one
  45:         br      zero
  46: 
  47: ine4:
  48:         jsr     pc,compar
  49:         bne     one
  50:         br      zero
  51:         bne     one
  52:         br      zero
  53: 
  54: ige4:
  55:         jsr     pc,compar
  56:         bge     one
  57:         br      zero
  58:         bhis    one
  59:         br      zero
  60: 
  61: igt4:
  62:         jsr     pc,compar
  63:         bgt     one
  64:         br      zero
  65:         bhi     one
  66:         br      zero
  67: 
  68: one:
  69:         mov     $1,(sp)
  70:         jmp     *(r4)+
  71: 
  72: zero:
  73:         clr     (sp)
  74:         jmp     *(r4)+
  75: 
  76: compar:
  77:         mov     (sp)+,r0
  78:         mov     (sp)+,r1
  79:         mov     (sp)+,r2
  80:         cmp     (sp)+,r1
  81:         beq     1f
  82:         jmp     (r0)
  83: 1:
  84:         cmp     (sp),r2
  85:         jmp     4(r0)
  86: 
  87: lor2:
  88:         bis     (sp)+,(sp)
  89:         jmp     *(r4)+
  90: 
  91: lan2:
  92:         tst     (sp)+
  93:         bne     1f
  94:         clr     (sp)
  95: 1:
  96:         jmp     *(r4)+
  97: 
  98: lnt2:
  99:         tst     (sp)
 100:         beq     one
 101:         br      zero
 102: 
 103: ieq2:
 104: leq2:
 105:         cmp     (sp)+,(sp)
 106:         beq     one
 107:         br      zero
 108: 
 109: ilt2:   cmp     (sp)+,(sp)
 110:         bgt     one
 111:         br      zero
 112: 
 113: ile2:
 114:         cmp     (sp)+,(sp)
 115:         bge     one
 116:         br      zero
 117: 
 118: igt2:
 119:         cmp     (sp)+,(sp)
 120:         blt     one
 121:         br      zero
 122: 
 123: ige2:
 124:         cmp     (sp)+,(sp)
 125:         ble     one
 126:         br      zero
 127: 
 128: ine2:
 129: lne2:
 130:         cmp     (sp)+,(sp)
 131:         bne     one
 132:         br      zero
 133: 
 134: leq1:
 135:         cmpb    (sp)+,(sp)
 136:         beq     one
 137:         br      zero
 138: 
 139: lne1:
 140:         cmpb    (sp)+,(sp)
 141:         bne     one
 142:         br      zero

Defined functions