2.11BSD#431 - /usr/src/sys/conf/boot/brboot.s

   1: /*
   2:  *	SCCS id	@(#)brboot.s	2.0 (2.11BSD)	4/13/91
   3:  */
   4: #include "localopts.h"
   5: 
   6: /  The boot options and device are placed in the last SZFLAGS bytes
   7: /  at the end of core for the bootstrap.
   8: ENDCORE=        160000          / end of core, mem. management off
   9: SZFLAGS=        6               / size of boot flags
  10: BOOTOPTS=       2               / location of options, bytes below ENDCORE
  11: BOOTDEV=        4               / boot unit
  12: CHECKWORD=      6
  13: 
  14: .globl  _doboot, hardboot, _bootcsr
  15: .text
  16: _doboot:
  17:         mov     4(sp),r4        / boot options
  18:         mov     2(sp),r3        / boot device
  19: 
  20: #ifndef KERN_NONSEP
  21: /  If running separate I/D, need to turn off memory management.
  22: /  Call the routine unmap in low text, after setting up a jump
  23: /  in low data where the PC will be pointing.
  24: .globl  unmap
  25:         mov     $137,*$unmap+2          / jmp *$hardboot
  26:         mov     $hardboot,*$unmap+4
  27:         jmp     unmap
  28:         / "return" from unmap will be to hardboot in data
  29: .data
  30: #else
  31: /  Reset to turn off memory management
  32:         reset
  33: #endif
  34: 
  35: /  On power fail, hardboot is the entry point (map is already off)
  36: /  and the args are in r4 (RB_POWRFAIL), r3 (rootdev)
  37: 
  38: hardboot:
  39:         mov     r4, ENDCORE-BOOTOPTS
  40:         ash     $-3,r3          / shift out the partition number
  41:         bic     $!7,r3          / save only the drive number
  42:         mov     r3, ENDCORE-BOOTDEV
  43:         com     r4              / if CHECKWORD == ~bootopts, flags are believed
  44:         mov     r4, ENDCORE-CHECKWORD
  45: 1:
  46:         reset
  47: 
  48: /  The remainder of the code is dependent on the boot device.
  49: /  If you have a bootstrap ROM, just jump to the correct entry.
  50: /  Otherwise, use a BOOT opcode, if available;
  51: /  if necessary, read in block 0 to location 0 "by hand".
  52: 
  53: / BR bootstrap
  54: 
  55: brda =  10
  56: 
  57:         mov     _bootcsr, r1    / csr of boot device
  58:         add     $brda,r1
  59:         clr     (r1)            / disk address
  60:         clr     -(r1)           / cylinder address
  61:         clr     -(r1)           / bus address
  62:         mov     $-256.,-(r1)    / wc
  63:         mov     ENDCORE-BOOTDEV,r0
  64:         swab    r0              / unit number to high byte
  65:         bis     $5,r0           / read+go
  66:         mov     r0,-(r1)        / cs: read+go
  67: 1:      tstb    (r1)            / wait for ready
  68:         bge     1b
  69: 
  70:         mov     _bootcsr,r1     / put csr and
  71:         mov     ENDCORE-BOOTDEV,r0      /  unit where bootblock expects them
  72:         clr     pc              / transfer to zero

Defined functions

Defined variables